1、新增VPN拨号连接

步骤不再赘述

2、设置VPN连接属性

【重要】禁止连接后添加路由

3、创建一键拨号或断开脚本

【注意】

10.10.0.* 是连接VPN后获取到的IP网段

10.10.1.0 是需要走VPN的网段

@echo OFF&PUSHD %~DP0 &TITLE PPTP自动拨号
mode con cols=36 lines=20
color 20
Md "%WinDir%\System32\test_permissions" 2>nul||(echo.&echo 请使用右键"以管理员身份运行"!&&pause >nul&&exit)
Rd "%WinDir%\System32\test_permissions" 2>nul
SetLocal EnableDelayedExpansion

:Menu
cls
echo.
echo 请选择操作：
echo ==============================
echo.&echo 1.连接VPN
echo.
echo.&echo 2.断开VPN
echo.
echo.&echo q.退出
echo.
echo ==============================
set /p a=输入数字后回车：
IF NOT "%a%"=="" SET a=%a:~0,1%
if "%a%"=="1" cls & goto VPNUP
if "%a%"=="2" cls & goto VPNDOWN
if "%a%"=="q" exit
echo.&echo 输入无效，请重新输入！ 
pause >nul & cls & goto MENU

:VPNUP
echo.
rasdial 上海翼码 username "password"
echo.
for /f "tokens=16" %%i in ('ipconfig^|findstr "10.10.0."') do set ip=%%i
@echo VPN获取的IP地址:%ip%
@echo.&echo 刷新dns缓存
ipconfig /flushdns
@echo.&echo 添加路由
route add -p 10.10.1.0 mask 255.255.255.0 %ip% metric 5
@echo.
echo.&echo 拨号完成，任意键退出！&pause >nul 2>nul & goto MENU

:VPNDOWN
rasdial 上海翼码 /disconnect
@echo.&echo 释放IP地址
ipconfig /release
ipconfig /renew
@echo.&echo 删除路由
route delete 10.10.1.0
echo.&echo 断开完成，任意键退出！&pause >nul 2>nul & goto MENU